Recipe 5.11. Finding Common or Different Keys in Two Hashes
Author: Tom Christiansen & Nathan Torkington
Date: 1999-07-02T01:32:52Z

#

| Chapter 5 Hashes |

## 5.11. Finding Common or Different Keys in Two Hashes

### Problem

You need to find keys in one hash that are present in another hash or keys in one hash that are not present in another.

### Solution

Use `keys` to loop through the keys of one hash, checking whether each key is also in the other hash.

#### Find common keys

    my @common = ();
    foreach (keys %hash1) {
        push(@common, $_) if exists $hash2{$_};
    }
    # @common now contains common keys

#### Find keys from one hash that aren't in both

    my @this_not_that = ();
    foreach (keys %hash1) {
        push(@this_not_that, $_) unless exists $hash2{$_};
    }

### Discussion

Because we're finding common or different keys of the hashes, we can apply our earlier array recipes for finding common or different elements to arrays of the hashes' keys. For an explanation, see Recipe 4.8.

This code uses the difference technique to find non-citrus foods:

    # %food_color per the introduction

    # %citrus_color is a hash mapping citrus food name to its color.
    %citrus_color = ( Lemon  => "yellow",
                      Orange => "orange",
                      Lime   => "green" );

    # build up a list of non-citrus foods
    @non_citrus = ();

    foreach (keys %food_color) {
        push (@non_citrus, $_) unless exists $citrus_color{$_};
    }

### See Also

The "Variables" section of Chapter 2 of Programming Perl; the `each` function in perlfunc (1) and in Chapter 3 of Programming Perl

5.10. Merging Hashes |  | 5.12. Hashing References