Recipe 9.3. Copying or Moving a File
Author: Tom Christiansen & Nathan Torkington
Date: 1999-07-02T01:39:06Z

#

| Chapter 9 Directories |

## 9.3. Copying or Moving a File

### Problem

You need to copy a file, but Perl has no built-in copy command.

### Solution

Use the `copy` function from the standard File::Copy module:

    use File::Copy;
    copy($oldfile, $newfile);

You can do it by hand:

    open(IN,  "< $oldfile")                     or die "can't open $oldfile: $!";
    open(OUT, "> $newfile")                     or die "can't open $newfile: $!";

    $blksize = (stat IN)[11] || 16384;          # preferred block size?
    while ($len = sysread IN, $buf, $blksize) {
        if (!defined $len) {
            next if $! =~ /^Interrupted/;       # ^Z and fg
            die "System read error: $!\n";
        }
        $offset = 0;
        while ($len) {          # Handle partial writes.
            defined($written = syswrite OUT, $buf, $len, $offset)
                or die "System write error: $!\n";
            $len    -= $written;
            $offset += $written;
        };
    }

    close(IN);
    close(OUT);

Or you can call your system's copy program:

    system("cp $oldfile $newfile");       # unix
    system("copy $oldfile $newfile");     # dos, vms

### Discussion

The File::Copy module provides `copy` and `move` functions. These are more convenient than resorting to low-level I/O calls and more portable than calling `system`. `move` works across file-system boundaries; the standard Perl built-in `rename` (usually) does not.

    use File::Copy;

    copy("datafile.dat", "datafile.bak")
        or die "copy failed: $!";

    move("datafile.new", "datafile.dat")
        or die "move failed: $!";

Because these functions return only a simple success status, you can't easily tell which file prevented the copy or move from being done. Copying the files manually lets you pinpoint which files didn't copy, but it fills your program with complex `sysread`s and `syswrite`s.

### See Also

Documentation for the standard File::Copy module (also in Chapter 7 of Programming Perl); the `rename`, `read`, and `syswrite` functions in perlfunc (1) and in Chapter 3 of Programming Perl

9.2. Deleting a File |  | 9.4. Recognizing Two Names for the Same File