Recipe 17.8. Finding Your Own Name and Address
Author: Tom Christiansen & Nathan Torkington
Date: 1999-07-02T01:44:33Z

#

| Chapter 17 Sockets |

## 17.8. Finding Your Own Name and Address

### Problem

You want to find your (fully qualified) hostname.

### Solution

First, get your (possibly qualified) hostname. Either try the standard Sys::Hostname module:

    use Sys::Hostname;

    $hostname = hostname();

or POSIX's `uname` function:

    use POSIX qw(uname);
    ($kernel, $hostname, $release, $version, $hardware) = uname();

    $hostname = (uname)[1];             # or just one

Then turn it into an IP address and convert to its canonical name:

    use Socket;                         # for AF_INET
    $address  = gethostbyname($hostname)
        or die "Couldn't resolve $hostname : $!";
    $hostname = gethostbyaddr($address, AF_INET)
        or die "Couldn't re-resolve $hostname : $!";

### Discussion

Sys::Hostname tries to be portable by using knowledge about your system to decide how best to find the hostname. It tries many different ways of getting the hostname, but several involve running other programs. This can lead to tainted data (see Recipe 19.1).

`POSIX::uname`, on the other hand, only works on POSIX systems and isn't guaranteed to provide anything useful in the `nodename` field that we are examining. That said, the value is useful on many machines and doesn't suffer from the tainted data problem that Sys::Hostname does.

Once you have the name, though, you must consider that it might be missing a domain name. For instance, Sys::Hostname may return you `guanaco` instead of `guanaco.camelids.org`. To fix this, convert the name back into an IP address with `gethostbyname` and then back into a name again with `gethostbyaddr`. By involving the domain name system, you are guaranteed of getting a full name.

### See Also

The `gethostbyaddr`, `gethostbyname` functions in Chapter 3 of Programming Perl and in perlfunc (1); the documentation for the standard Net::hostent and Sys::Hostname modules

17.7. Identifying the Other End of a Socket |  | 17.9. Closing a Socket After Forking