Recipe 7.10. Modifying a File in Place Without a Temporary File
Author: Tom Christiansen & Nathan Torkington
Date: 1999-07-02T01:36:34Z

#

| Chapter 7 File Access |

## 7.10. Modifying a File in Place Without a Temporary File

### Problem

You need to insert, delete, or change one or more lines in a file, and you don't want to (or can't) use a temporary file.

### Solution

Open the file in update mode (`"+<"`), read the whole file into an array of lines, change the array, then rewrite the file and truncate it to its current seek pointer.

    open(FH, "+< FILE")                 or die "Opening: $!";
    @ARRAY = <FH>;
    # change ARRAY here
    seek(FH,0,0)                        or die "Seeking: $!";
    print FH @ARRAY                     or die "Printing: $!";
    truncate(FH,tell(FH))               or die "Truncating: $!";
    close(FH)                           or die "Closing: $!";

### Discussion

As explained in the Introduction, the operating system treats files as unstructured streams of bytes. This makes it impossible to insert, modify, or change bits of the file in place. (Except for the special case of fixed-record-length files, discussed in Recipe 8.13.) You can use a temporary file to hold the changed output, or you can read the entire file into memory, change it, and write it back out again.

Reading everything into memory works for small files, but it doesn't scale well. Trying it on your 800 MB web server log files will either deplete your virtual memory or thrash your machine's VM system. For small files, though, this works:

    open(F, "+< $infile")       or die "can't read $infile: $!";
    $out = '';
    while (<F>) {
        s/DATE/localtime/eg;
        $out .= $_;
    }
    seek(F, 0, 0)               or die "can't seek to start of $infile: $!";
    print F $out                or die "can't print to $infile: $!";
    truncate(F, tell(F))        or die "can't truncate $infile: $!";
    close(F)                    or die "can't close $infile: $!";

For other examples of the things you can do in-place, look at the recipes in Chapter 8.

This approach is for the truly determined. It's harder to write, takes more memory (potentially a lot more), doesn't keep a backup file, and may confuse other processes trying to read from the file you're updating. For most purposes, therefore, we suggest it's probably not worth it.

Remember to lock if you're paranoid.

### See Also

The `seek`, `truncate`, `open`, `sysopen` functions in perlfunc (1) and in Chapter 3 of Programming Perl; Recipe 7.8; Recipe 7.9

7.9. Modifying a File in Place with -i Switch |  | 7.11. Locking a File